-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
172 lines (154 loc) · 4.5 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
/*
* The Maven coordinates for the project artifact
*/
description='The INCOSE example project'
group = 'io.opencaesar.ontologies'
version = '2.0.0'
/*
* The Gradle task dependencies
*/
buildscript {
repositories {
mavenLocal()
mavenCentral()
}
dependencies {
classpath 'io.opencaesar.owl:owl-fuseki-gradle:2.+'
classpath 'io.opencaesar.owl:owl-query-gradle:2.+'
classpath 'io.opencaesar.owl:owl-load-gradle:2.+'
classpath 'io.opencaesar.owl:owl-reason-gradle:2.+'
classpath 'io.opencaesar.oml:oml-merge-gradle:2.+'
classpath 'io.opencaesar.adapters:oml2owl-gradle:2.+'
}
}
/*
* The configuration of OML dependencies
*/
configurations {
oml
}
/*
* The repositories to look up OML dependencies in
*/
repositories {
mavenLocal()
mavenCentral()
}
/*
* The OML dependencies
*/
dependencies {
oml "io.opencaesar.ontologies:core-vocabularies:5.+"
}
/*
* A task to extract and merge the OML dependencies
*/
task downloadDependencies(type:io.opencaesar.oml.merge.OmlMergeTask) {
inputZipPaths = configurations.oml.files
outputCatalogFolder = file('build/oml')
}
/*
* A task to convert the OML catalog to OWL catalog
*/
task omlToOwl(type:io.opencaesar.oml2owl.Oml2OwlTask, dependsOn: downloadDependencies) {
// OML catalog
inputCatalogPath = file('catalog.xml')
// OWL catalog
outputCatalogPath = file('build/owl/catalog.xml')
}
/*
* A task to run the Openllet reasoner on the OWL catalog
*/
task owlReason(type:io.opencaesar.owl.reason.OwlReasonTask, dependsOn: omlToOwl) {
// OWL catalog
catalogPath = file('build/owl/catalog.xml')
// Input ontology IRI to reason on
inputOntologyIri = 'http://incose.org/pwg/s-star/description/power-converter-bundle'
// Entailment statements to generate and the ontologies to persist them in
specs = [
'http://incose.org/pwg/s-star/bundle/classes = ALL_SUBCLASS',
'http://incose.org/pwg/s-star/bundle/properties = INVERSE_PROPERTY | ALL_SUBPROPERTY',
'http://incose.org/pwg/s-star/bundle/individuals = ALL_INSTANCE | DATA_PROPERTY_VALUE | OBJECT_PROPERTY_VALUE | SAME_AS'
]
// Junit error report
reportPath = file('build/reports/reasoning.xml')
}
/*
* Start and stop the Fuseki server
*/
task startFuseki(type: io.opencaesar.owl.fuseki.StartFusekiTask) {
configurationPath = file('.fuseki.ttl')
outputFolderPath = file('.fuseki')
}
task stopFuseki(type: io.opencaesar.owl.fuseki.StopFusekiTask) {
outputFolderPath = file('.fuseki')
}
/*
* A task to load an OWL catalog to a Fuseki dataset endpoint
*/
task owlLoad(type:io.opencaesar.owl.load.OwlLoadTask, dependsOn: owlReason) {
inputs.files(startFuseki.outputFolderPath) // rerun when fuseki restarts
catalogPath = file('build/owl/catalog.xml')
endpointURL = 'http://localhost:3030/incose'
fileExtensions = ['owl', 'ttl']
iris = [
'http://incose.org/pwg/s-star/bundle/classes',
'http://incose.org/pwg/s-star/bundle/properties',
'http://incose.org/pwg/s-star/bundle/individuals'
]
}
/*
* A task to run a set of SPARQL queries on a Fuseki dataset endpoint
*/
task owlQuery(type:io.opencaesar.owl.query.OwlQueryTask, dependsOn: owlLoad) {
endpointURL = 'http://localhost:3030/incose'
queryPath = file('src/sparql')
resultPath = file('build/frames')
format = 'tsv'
}
/*
* A task to build the project, which executes several tasks together
*/
task build() {
dependsOn owlReason
}
/*
* A task to delete the build artifacts
*/
task clean(type: Delete) {
delete 'build'
}
/*
* Publish to Maven spec
*/
apply plugin: 'maven-publish'
task omlZip(type: Zip) {
from file('src/oml')
include "**/*.oml"
destinationDirectory = file('build/libs')
archiveBaseName = project.name
archiveVersion = project.version
}
publishing {
publications {
maven(MavenPublication) {
artifact omlZip
pom.withXml {
def dependencies = asNode().appendNode('dependencies')
configurations.oml.allDependencies.stream().each {
def dependency = dependencies.appendNode('dependency')
dependency.appendNode('groupId', it.group)
dependency.appendNode('artifactId', it.name)
dependency.appendNode('version', it.version)
}
}
}
}
}
/*
* Integration with the Eclipse IDE
*/
apply plugin: 'eclipse'
eclipse {
synchronizationTasks downloadDependencies
}