НЕ ТЕСТИРОВАЛОСЬ!!! Интегрирована доработка от Yusupoff (AlexGyver#5)…

…. НЕ ТЕСТИРОВАЛОСЬ!!!

firmware/GyverLamp_v1.4.1/GyverLamp_v1.4.1.ino

@@ -0,0 +1,273 @@
+/*
+  Скетч к проекту "Многофункциональный RGB светильник"
+  Страница проекта (схемы, описания): https://alexgyver.ru/GyverLamp/
+  Исходники на GitHub: https://github.com/AlexGyver/GyverLamp/
+  Нравится, как написан код? Поддержи автора! https://alexgyver.ru/support_alex/
+  Автор: AlexGyver, AlexGyver Technologies, 2019
+  https://AlexGyver.ru/
+*/
+
+/*
+  Версия 1.4:
+  - Исправлен баг при смене режимов
+  - Исправлены тормоза в режиме точки доступа
+
+  Дополнение:
+  Есть константа const char HOSTNAME[] = "GyverLamp";
+  Значение которую можно вводить вместо адреса в программе
+  HOSTNAME это имя клиента сети
+*/
+
+// Ссылка для менеджера плат:
+// http://arduino.esp8266.com/stable/package_esp8266com_index.json
+
+// ============= НАСТРОЙКИ =============
+// -------- ВРЕМЯ -------
+#define GMT 3              // смещение (москва 3)
+#define NTP_ADDRESS  "europe.pool.ntp.org"    // сервер времени
+
+// -------- РАССВЕТ -------
+#define DAWN_BRIGHT 200       // макс. яркость рассвета
+#define DAWN_TIMEOUT 1        // сколько рассвет светит после времени будильника, минут
+
+// ---------- МАТРИЦА ---------
+#define BRIGHTNESS 40         // стандартная маскимальная яркость (0-255)
+#define CURRENT_LIMIT 2000    // лимит по току в миллиамперах, автоматически управляет яркостью (пожалей свой блок питания!) 0 - выключить лимит
+
+#define WIDTH 16              // ширина матрицы
+#define HEIGHT 16             // высота матрицы
+
+#define COLOR_ORDER GRB       // порядок цветов на ленте. Если цвет отображается некорректно - меняйте. Начать можно с RGB
+
+#define MATRIX_TYPE 0         // тип матрицы: 0 - зигзаг, 1 - параллельная
+#define CONNECTION_ANGLE 0    // угол подключения: 0 - левый нижний, 1 - левый верхний, 2 - правый верхний, 3 - правый нижний
+#define STRIP_DIRECTION 0     // направление ленты из угла: 0 - вправо, 1 - вверх, 2 - влево, 3 - вниз
+// при неправильной настройке матрицы вы получите предупреждение "Wrong matrix parameters! Set to default"
+// шпаргалка по настройке матрицы здесь! https://alexgyver.ru/matrix_guide/
+
+// --------- ESP --------
+const char HOSTNAME[] = "PaprikaLamp";
+#define ESP_MODE 1
+// 0 - точка доступа
+// 1 - локальный
+byte IP_AP[] = {192, 168, 4, 4};   // статический IP точки доступа (менять только последнюю цифру)
+
+//#define WIFIMGR_PORTAL_TIMEOUT 1
+//#define WIFIMGR_SET_MANUAL_IP
+#ifdef WIFIMGR_SET_MANUAL_IP
+  char static_ip[16] = "192.168.1.56";
+  char static_gw[16] = "192.168.1.1";
+  char static_sn[16] = "255.255.255.0";
+#endif
+
+// ----- AP (точка доступа) -------
+#define AP_SSID "PaprikaLamp"
+#define AP_PASS "12345678"
+#define AP_PORT 8888
+
+// -------- Менеджер WiFi ---------
+#define AC_SSID "AutoAP"
+#define AC_PASS "12345678"
+
+// ============= ДЛЯ РАЗРАБОТЧИКОВ =============
+#define LED_PIN 2             // пин ленты
+#define BTN_PIN 4
+#define MODE_AMOUNT 18
+
+#define NUM_LEDS WIDTH * HEIGHT
+#define SEGMENTS 1            // диодов в одном "пикселе" (для создания матрицы из кусков ленты)
+// ---------------- БИБЛИОТЕКИ -----------------
+#define FASTLED_INTERRUPT_RETRY_COUNT 0
+#define FASTLED_ALLOW_INTERRUPTS 0
+#define FASTLED_ESP8266_RAW_PIN_ORDER
+#define NTP_INTERVAL 60 * 1000    // обновление (1 минута)
+
+#include "timerMinim.h"
+#include <FastLED.h>
+#include <ESP8266WiFi.h>
+#include <DNSServer.h>
+#include <ESP8266WebServer.h>
+#include <WiFiManager.h>
+#include <WiFiUdp.h>
+#include <EEPROM.h>
+#include <NTPClient.h>
+#include <GyverButton.h>
+
+// ------------------- ТИПЫ --------------------
+CRGB leds[NUM_LEDS];
+WiFiServer server(80);
+WiFiUDP Udp;
+WiFiUDP ntpUDP;
+NTPClient timeClient(ntpUDP, NTP_ADDRESS, GMT * 3600, NTP_INTERVAL);
+timerMinim timeTimer(3000);
+GButton touch(BTN_PIN, LOW_PULL, NORM_OPEN);
+
+// ----------------- ПЕРЕМЕННЫЕ ------------------
+const char* autoConnectSSID = AC_SSID;
+const char* autoConnectPass = AC_PASS;
+const char AP_NameChar[] = AP_SSID;
+const char WiFiPassword[] = AP_PASS;
+unsigned int localPort = AP_PORT;
+char packetBuffer[UDP_TX_PACKET_MAX_SIZE + 1]; //buffer to hold incoming packet
+String inputBuffer;
+static const byte maxDim = max(WIDTH, HEIGHT);
+struct {
+  byte brightness = 50;
+  byte speed = 30;
+  byte scale = 40;
+} modes[MODE_AMOUNT];
+
+struct {
+  boolean state = false;
+  int time = 0;
+} alarm[7];
+
+byte dawnOffsets[] = {5, 10, 15, 20, 25, 30, 40, 50, 60};
+byte dawnMode;
+boolean dawnFlag = false;
+long thisTime;
+boolean manualOff = false;
+
+int8_t currentMode = 0;
+boolean loadingFlag = true;
+boolean ONflag = true;
+uint32_t eepromTimer;
+boolean settChanged = false;
+// Конфетти, Огонь, Радуга верт., Радуга гориз., Смена цвета,
+// Безумие 3D, Облака 3D, Лава 3D, Плазма 3D, Радуга 3D,
+// Павлин 3D, Зебра 3D, Лес 3D, Океан 3D,
+
+unsigned char matrixValue[8][16];
+
+void setup() {
+  //ESP.wdtDisable();
+  //ESP.wdtEnable(WDTO_8S);
+  wifi_station_set_hostname(const_cast<char*>(HOSTNAME));
+
+  // ЛЕНТА
+  FastLED.addLeds<WS2812B, LED_PIN, COLOR_ORDER>(leds, NUM_LEDS)/*.setCorrection( TypicalLEDStrip )*/;
+  FastLED.setBrightness(BRIGHTNESS);
+  if (CURRENT_LIMIT > 0) FastLED.setMaxPowerInVoltsAndMilliamps(5, CURRENT_LIMIT);
+  FastLED.clear();
+  FastLED.show();
+
+  touch.setStepTimeout(100);
+  touch.setClickTimeout(500);
+
+  Serial.begin(115200);
+  Serial.println();
+
+  // WI-FI
+  if (ESP_MODE == 0) {    // режим точки доступа
+    WiFi.softAPConfig(IPAddress(IP_AP[0], IP_AP[1], IP_AP[2], IP_AP[3]),
+                      IPAddress(192, 168, 4, 1),
+                      IPAddress(255, 255, 255, 0));
+
+    WiFi.softAP(AP_NameChar, WiFiPassword);
+    IPAddress myIP = WiFi.softAPIP();
+    Serial.print("Access point Mode");
+    Serial.print("AP IP address: ");
+    Serial.println(myIP);
+
+    server.begin();
+  } else {                // подключаемся к роутеру
+    Serial.print("WiFi manager");
+    WiFiManager wifiManager;
+
+    #ifdef WIFIMGR_SET_MANUAL_IP
+            IPAddress _ip, _gw, _sn;
+            _ip.fromString(static_ip);
+            _gw.fromString(static_gw);
+            _sn.fromString(static_sn);
+            wifiManager.setSTAStaticIPConfig(_ip, _gw, _sn);
+    #endif
+    #ifdef WIFIMGR_PORTAL_TIMEOUT
+            wifiManager.setConfigPortalTimeout(WIFIMGR_PORTAL_TIMEOUT);
+    #endif
+            wifiManager.autoConnect(HOSTNAME);
+
+    wifiManager.setDebugOutput(false);
+    //wifiManager.resetSettings();
+
+    Serial.print("Connected! IP address: ");
+    Serial.println("local ip");
+    Serial.println(WiFi.localIP());
+    Serial.println(WiFi.gatewayIP());
+    Serial.println(WiFi.subnetMask());
+    server.begin();
+  }
+  Serial.printf("UDP server on port %d\n", localPort);
+  Udp.begin(localPort);
+
+  // EEPROM
+  EEPROM.begin(202);
+  delay(50);
+  if (EEPROM.read(198) != 20) {   // первый запуск
+    EEPROM.write(198, 20);
+    EEPROM.commit();
+
+    for (byte i = 0; i < MODE_AMOUNT; i++) {
+      EEPROM.put(3 * i + 40, modes[i]);
+      EEPROM.commit();
+    }
+    for (byte i = 0; i < 7; i++) {
+      EEPROM.write(5 * i, alarm[i].state);   // рассвет
+      eeWriteInt(5 * i + 1, alarm[i].time);
+      EEPROM.commit();
+    }
+    EEPROM.write(199, 0);   // рассвет
+    EEPROM.write(200, 0);   // режим
+    EEPROM.commit();
+  }
+  for (byte i = 0; i < MODE_AMOUNT; i++) {
+    EEPROM.get(3 * i + 40, modes[i]);
+  }
+  for (byte i = 0; i < 7; i++) {
+    alarm[i].state = EEPROM.read(5 * i);
+    alarm[i].time = eeGetInt(5 * i + 1);
+  }
+  dawnMode = EEPROM.read(199);
+  currentMode = (int8_t)EEPROM.read(200);
+
+  // отправляем настройки
+  sendCurrent();
+  char reply[inputBuffer.length() + 1];
+  inputBuffer.toCharArray(reply, inputBuffer.length() + 1);
+  Udp.beginPacket(Udp.remoteIP(), Udp.remotePort());
+  Udp.write(reply);
+  Udp.endPacket();
+
+  timeClient.begin();
+  memset(matrixValue, 0, sizeof(matrixValue));
+
+  randomSeed(micros());
+}
+
+void loop() {
+  parseUDP();
+  effectsTick();
+  eepromTick();
+  timeTick();
+  buttonTick();
+  //ESP.wdtFeed();   // пнуть собаку
+  yield();
+}
+
+void eeWriteInt(int pos, int val) {
+  byte* p = (byte*) &val;
+  EEPROM.write(pos, *p);
+  EEPROM.write(pos + 1, *(p + 1));
+  EEPROM.write(pos + 2, *(p + 2));
+  EEPROM.write(pos + 3, *(p + 3));
+  EEPROM.commit();
+}
+
+int eeGetInt(int pos) {
+  int val;
+  byte* p = (byte*) &val;
+  *p        = EEPROM.read(pos);
+  *(p + 1)  = EEPROM.read(pos + 1);
+  *(p + 2)  = EEPROM.read(pos + 2);
+  *(p + 3)  = EEPROM.read(pos + 3);
+  return val;
+}

firmware/GyverLamp_v1.4.1/button.ino

@@ -0,0 +1,59 @@
+boolean brightDirection;
+
+void buttonTick() {
+  touch.tick();
+  if (touch.isSingle()) {
+    if (dawnFlag) {
+      manualOff = true;
+      dawnFlag = false;
+      loadingFlag = true;
+      FastLED.setBrightness(modes[currentMode].brightness);
+      changePower();
+    } else {
+      if (ONflag) {
+        ONflag = false;
+        changePower();
+      } else {
+        ONflag = true;
+        changePower();
+      }
+    }
+  }
+
+  if (ONflag && touch.isDouble()) {
+    if (++currentMode >= MODE_AMOUNT) currentMode = 0;
+    FastLED.setBrightness(modes[currentMode].brightness);
+    loadingFlag = true;
+    settChanged = true;
+    eepromTimer = millis();
+    FastLED.clear();
+    delay(1);
+  }
+  if (ONflag && touch.isTriple()) {
+    if (--currentMode < 0) currentMode = 0;
+    FastLED.setBrightness(modes[currentMode].brightness);
+    loadingFlag = true;
+    settChanged = true;
+    eepromTimer = millis();
+    FastLED.clear();
+    delay(1);
+  }
+
+  if (ONflag && touch.isHolded()) {
+    brightDirection = !brightDirection;
+  }
+  if (ONflag && touch.isStep()) {
+    if (brightDirection) {
+      if (modes[currentMode].brightness < 10) modes[currentMode].brightness += 1;
+      else if (modes[currentMode].brightness < 250) modes[currentMode].brightness += 5;
+      else modes[currentMode].brightness = 255;
+    } else {
+      if (modes[currentMode].brightness > 15) modes[currentMode].brightness -= 5;
+      else if (modes[currentMode].brightness > 1) modes[currentMode].brightness -= 1;
+      else modes[currentMode].brightness = 1;
+    }
+    FastLED.setBrightness(modes[currentMode].brightness);
+    settChanged = true;
+    eepromTimer = millis();
+  }
+}

firmware/GyverLamp_v1.4.1/eeprom.ino

@@ -0,0 +1,25 @@
+void saveEEPROM() {
+  EEPROM.put(3 * currentMode + 40, modes[currentMode]);
+  EEPROM.commit();
+}
+
+void eepromTick() {
+  if (settChanged && millis() - eepromTimer > 30000) {
+    settChanged = false;
+    eepromTimer = millis();
+    saveEEPROM();
+    if (EEPROM.read(200) != currentMode) EEPROM.write(200, currentMode);
+    EEPROM.commit();
+  }
+}
+
+void saveAlarm(byte almNumber) {
+  EEPROM.write(5 * almNumber, alarm[almNumber].state);   // рассвет
+  eeWriteInt(5 * almNumber + 1, alarm[almNumber].time);
+  EEPROM.commit();
+}
+
+void saveDawnMmode() {
+  EEPROM.write(199, dawnMode);   // рассвет
+  EEPROM.commit();
+}