Introduce status code response binding in the client side

[TharmiganK]

Purpose

$Subject

Fixes: ballerina-platform/ballerina-library#6100

Examples

• Service sample:

import ballerina/http;

type Album record {|
    readonly string id;
    string name;
    string artist;
    string genre;
|};

table<Album> key(id) albums = table [
    {id: "1", name: "The Dark Side of the Moon", artist: "Pink Floyd", genre: "Progressive Rock"},
    {id: "2", name: "Back in Black", artist: "AC/DC", genre: "Hard Rock"},
    {id: "3", name: "The Wall", artist: "Pink Floyd", genre: "Progressive Rock"}
];

type ErrorMessage record {|
    string albumId;
    string message;
|};

type Headers record {|
    string user\-id;
    int req\-id;
|};

type AlbumNotFound record {|
    *http:NotFound;
    ErrorMessage body;
    Headers headers;
|};

type AlbumFound record {|
    *http:Ok;
    Album body;
    Headers headers;
|};

service /api on new http:Listener(9090) {

    resource function get albums/[string id]() returns AlbumFound|AlbumNotFound {
        if albums.hasKey(id) {
            return {
                body: albums.get(id),
                headers: {user\-id: "user-1", req\-id: 1}
            };
        }
        return {
            body: {albumId: id, message: "Album not found"},
            headers: {user\-id: "user-1", req\-id: 1}
        };
    }
}

• Client sample

import ballerina/http;

type Album record {|
    readonly string id;
    string name;
    string artist;
    string genre;
|};

type ErrorMessage record {|
    string albumId;
    string message;
|};

type Headers record {|
    string user\-id;
    int req\-id;
|};

type AlbumNotFound record {|
    *http:NotFound;
    ErrorMessage body;
    Headers headers;
|};

type AlbumFound record {|
    *http:Ok;
    Album body;
    Headers headers;
|};

final http:Client albumClient = check new("http://localhost:9090/api");

public function main() returns error? {
    Album _ = check albumClient->/albums/'1;

    AlbumFound _ = check albumClient->/albums/'1;

    Album|AlbumNotFound _ = check albumClient->/albums/'1;

    AlbumFound|AlbumNotFound _ = check albumClient->/albums/'1;

    Album|http:Response _ = check albumClient->/albums/'1;
}

Checklist

• Linked to an issue
• Updated the changelog
• Added tests
• Updated the spec - will be added via Update HTTP spec with the status code response binding in the client side ballerina-library#6289
• Checked native-image compatibility
• Checked the impact on OpenAPI generation - Added via Add status code response binding in the generated client openapi-tools#1634

[codecov]

Codecov Report

Attention: Patch coverage is 91.34328% with 29 lines in your changes are missing coverage. Please review.

Project coverage is 81.56%. Comparing base (ba6e691) to head (4e49fc3).
Report is 1 commits behind head on master.

Files	Patch %	Lines
...b/http/api/nativeimpl/ExternResponseProcessor.java	90.20%	21 Missing and 7 partials ⚠️
...ib/http/api/service/signature/AllHeaderParams.java	85.71%	1 Missing ⚠️

Additional details and impacted files

@@             Coverage Diff              @@
##             master    #1915      +/-   ##
============================================
- Coverage     81.78%   81.56%   -0.22%     
  Complexity      562      562              
============================================
  Files           393      387       -6     
  Lines         21516    21401     -115     
  Branches       4802     4855      +53     
============================================
- Hits          17597    17456     -141     
- Misses         2925     2942      +17     
- Partials        994     1003       +9     

☔ View full report in Codecov by Sentry.
📢 Have feedback on the report? Share it here.

[sonarcloud]

Quality Gate passed

Issues
2 New issues
0 Accepted issues

Measures
0 Security Hotspots
No data about Coverage
0.0% Duplication on New Code

See analysis details on SonarCloud