-
Notifications
You must be signed in to change notification settings - Fork 1
/
flake.nix
149 lines (133 loc) · 4.07 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
{
description = "Uv2nix";
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
treefmt-nix.url = "github:numtide/treefmt-nix";
treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";
nix-github-actions.url = "github:nix-community/nix-github-actions";
nix-github-actions.inputs.nixpkgs.follows = "nixpkgs";
pyproject-nix.url = "github:nix-community/pyproject.nix";
pyproject-nix.inputs.nixpkgs.follows = "nixpkgs";
pyproject-nix.inputs.nix-github-actions.follows = "nix-github-actions";
pyproject-nix.inputs.mdbook-nixdoc.follows = "mdbook-nixdoc";
pyproject-nix.inputs.treefmt-nix.follows = "treefmt-nix";
pyproject-nix.inputs.lix-unit.follows = "lix-unit";
mdbook-nixdoc.url = "github:adisbladis/mdbook-nixdoc";
mdbook-nixdoc.inputs.nixpkgs.follows = "nixpkgs";
mdbook-nixdoc.inputs.nix-github-actions.follows = "nix-github-actions";
lix-unit = {
url = "github:adisbladis/lix-unit";
inputs.mdbook-nixdoc.follows = "mdbook-nixdoc";
inputs.nix-github-actions.follows = "nix-github-actions";
inputs.nixpkgs.follows = "nixpkgs";
inputs.treefmt-nix.follows = "treefmt-nix";
};
};
outputs =
{
self,
nixpkgs,
treefmt-nix,
pyproject-nix,
nix-github-actions,
lix-unit,
...
}@inputs:
let
forAllSystems = lib.genAttrs lib.systems.flakeExposed;
inherit (nixpkgs) lib;
in
{
githubActions = nix-github-actions.lib.mkGithubMatrix {
checks = {
inherit (self.checks) x86_64-linux;
};
};
lib = import ./lib {
inherit pyproject-nix;
inherit lib;
};
templates =
let
root = ./templates;
dirs = lib.attrNames (lib.filterAttrs (_: type: type == "directory") (builtins.readDir root));
in
lib.listToAttrs (
map (
dir:
let
path = root + "/${dir}";
template = import (path + "/flake.nix");
in
lib.nameValuePair dir {
inherit path;
inherit (template) description;
}
) dirs
);
# Expose unit tests for external discovery
libTests = import ./lib/test.nix {
inherit lib pyproject-nix;
uv2nix = self.lib;
pkgs = nixpkgs.legacyPackages.x86_64-linux;
};
devShells = forAllSystems (
system:
let
pkgs = nixpkgs.legacyPackages.${system};
mkShell' =
{ nix-unit }:
pkgs.mkShell {
packages = [
pkgs.hivemind
pkgs.mdbook
pkgs.reflex
nix-unit
inputs.mdbook-nixdoc.packages.${system}.default
self.packages.${system}.uv-bin
pkgs.python3
] ++ self.packages.${system}.doc.nativeBuildInputs;
shellHook = ''
UV_NO_SYNC=1
'';
};
in
{
nix = mkShell' { inherit (pkgs) nix-unit; };
lix = mkShell' { nix-unit = lix-unit.packages.${system}.default; };
default = self.devShells.${system}.nix;
}
);
checks = forAllSystems (
system:
let
pkgs = nixpkgs.legacyPackages.${system};
in
builtins.removeAttrs self.packages.${system} [ "default" ]
// import ./dev/checks.nix {
inherit pyproject-nix pkgs lib;
uv2nix = self.lib;
}
);
packages = forAllSystems (
system:
let
pkgs = nixpkgs.legacyPackages.${system};
in
{
doc = pkgs.callPackage ./doc {
inherit self;
mdbook-nixdoc = inputs.mdbook-nixdoc.packages.${system}.default;
};
uv-bin = pkgs.callPackage ./pkgs/uv-bin { };
}
);
formatter = forAllSystems (
system:
let
pkgs = nixpkgs.legacyPackages.${system};
in
(treefmt-nix.lib.evalModule pkgs ./dev/treefmt.nix).config.build.wrapper
);
};
}