FlxGroup add to end of members

[NQNStudios]

Currently, FlxGroup.add() has no option to guarantee that the new object will be added at the end of its member array. If I want to remove() and add() an object to bring it visually to the front of the game, I can only do that if I remember to call remove() with the splice argument true every time. Additionally, if I use any library/plugin that calls remove() without splice, I open myself up to Z-sorting errors.

I could manually push() the element to members, but this won't update the FlxGroup's length.

I suggest that add() could take an optional "at end" argument, which guarantees that the given object is push()ed onto members, not put at the first null index.

[NQNStudios]

I think the best available workaround at this point is to manually splice members to remove every null index before calling add().

[Geokureli]

Agreed, I think you should splice members when removing to ensure that there are no null indices in the group. this is what I do. There are also a lot of techniques to use when z-order is important, like using FlxSort on groups, or having foreground, midground, and background groups to ensure different objects always appear on top or bottom of each other.

Gonna convert this to a discussion, since it's not a technical issue, more of a tip or methodology

[NQNStudios]

So what I actually did is make sure to use remove() with the splice flag in my code, and ALSO because on principle, I might unwittingly call a haxelib or addon's code that may remove() without the flag, thus leaving a null gap, I did a loop to explicitly remove null gaps before calling add() again.

group.remove(sprite, true);
while (group.members.indexOf(null) != -1) {
    group.members.splice(group.members.lastIndexOf(null), 1);
}
group.add(sprite);

[NQNStudios]

A constant-time (and more ergonomic) way to provide the behavior I want, would be a new signature for FlxGroup.add():

function add(obj:T, push:Bool=false) where providing true for push makes add() skip the check for null gaps, and just push() onto the underlying members array (unless maxSize is already reached, etc.).

[Geokureli]

that seems like a lot of work when just adding an extra arg would suffice

[NQNStudios]

The point of this cautious approach is that it guarantees mistakes made in random other parts of my codebase, don't break the behavior of my bringToFront() method at runtime.

[Geokureli]

if you really want to prevent it you can use abstracts to define you're own group behaviors.

@:forward
abstract SpliceGroup (FlxGroup) from FlxGroup to FlxGroup
{
    inline public function new (maxSize = 0)
    {
        this = new FlxGroup(maxSize);
    }

    inline public function remove (obj:FlxBasic)
    {
        this.remove(obj, true);
    }
}

and to create one:

var group = new SpliceGroup();

note that this is not inheritance, passing a SpliceGroup into a function that accepts a FlxGroup and calls remove will call the FlxGroup's remove func

[NQNStudios]

I would rather be able to provide a function bringToFront() that always works, than a function bringToFront() with a caveat in the documentation that if you forget to splice-remove, it will break.

[Geokureli]

you can even add a bringToFront method making it

@:forward
abstract SpliceGroup (FlxGroup) from FlxGroup to FlxGroup
{
    inline public function new (maxSize = 0)
    {
        this = new FlxGroup(maxSize);
    }

    inline public function remove (obj:FlxBasic)
    {
        this.remove(obj, true);
    }
    
    inline public function bringToFront(obj:FlxBasic)
    {
        if (this.members.contains(obj))
        {
            this.members.remove(obj);
            this.members.push(obj);
        }
        return obj;
    }
}

that "always works" without needing to clear the group every time, which is a caveat preventing your tool from working for everyone

edited

[NQNStudios]

You're right, this is the best way. I didn't think of it because I was hung up on how modifying members directly would leave length unchanged -- not realizing that when you bump an element to the end, the length stays the same anyway.

[Geokureli]

after doing some research I changed my method around about 5 seconds ago, I recommend the new version