-
Notifications
You must be signed in to change notification settings - Fork 1
/
agb.ld
75 lines (68 loc) · 1.92 KB
/
agb.ld
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
/****************************/
OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_entry)
/****************************/
/* Memory Layout */
MEMORY {
ewram : ORIGIN = 0x02000000, LENGTH = 256K
iwram : ORIGIN = 0x03000000, LENGTH = 32K - 8 /* Exclude BIOS.IRQFlag,BIOS.IRQProc and stacks */
rom : ORIGIN = 0x08000000, LENGTH = 32M /* Cartridge size cannot exceed 32MiB; wraps around */
}
__ewram_beg__ = ORIGIN(ewram);
__ewram_end__ = ORIGIN(ewram) + LENGTH(ewram);
__iwram_beg__ = ORIGIN(iwram);
__iwram_end__ = ORIGIN(iwram) + LENGTH(iwram);
__rom_beg__ = ORIGIN(rom);
__rom_end__ = ORIGIN(rom) + LENGTH(rom);
/* Stack Areas */
__sp_base = __iwram_end__;
__sp_irq_size = 0x00C0;
__sp_svc_size = 0x0040;
__sp_usr_size = 0x0300;
__sp_irq = __sp_base;
__sp_svc = __sp_base - __sp_irq_size;
__sp_usr = __sp_base - __sp_irq_size - __sp_svc_size;
/****************************/
SECTIONS {
/* ROM area */
.text : {
KEEP (*(.entry))
*(.text .text.*)
*(.stub)
*(.glue_7 .glue_7t)
} >rom
.rodata : {
*(.rodata .rodata.*)
*(.roda)
} >rom
__lma_area_beg__ = . ;
/* EWRAM area */
. = __ewram_beg__;
__ewram_lma_beg__ = __lma_area_beg__ ;
.ewram : AT(__ewram_lma_beg__) {
*(.data .data.*)
*(.ewram .ewram.*)
} >ewram
__ewram_lma_end__ = __ewram_lma_beg__ + SIZEOF(.ewram);
ASSERT(__ewram_lma_end__ < __rom_end__, "EWRAM overflow in ROM LMA")
.sbss (NOLOAD) : {
*(.sbss .sbss.*)
} >ewram
__ewram_heap_beg__ = . ;
__ewram_heap_end__ = __ewram_end__;
/* IWRAM area */
. = __iwram_beg__;
__iwram_lma_beg__ = __ewram_lma_end__;
.iwram : AT(__iwram_lma_beg__) {
*(.iwram .iwram.*)
} >iwram
__iwram_lma_end__ = __iwram_lma_beg__ + SIZEOF(.iwram);
ASSERT(__iwram_lma_end__ < __rom_end__, "IWRAM overflow in ROM LMA")
.bss (NOLOAD) : {
*(.bss .bss.*)
} >iwram
__iwram_heap_beg__ = . ;
__iwram_heap_end__ = __sp_usr - __sp_usr_size;
}
/****************************/